TestPage: comp2schema.xsl

<?xml version="1.0" encoding="UTF-8"?>

<!-- 
$Revision: 14516 $
$Date: 2009-03-25 16:36:01 +0100 (Wed, 25 Mar 2009) $
-->

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="2.0"
    xmlns:xs="http://www.w3.org/2001/XMLSchema" xmlns:dcr="http://www.isocat.org">
    <xsl:strip-space elements="*"/>
    <xsl:include href="comp2schema-header.xsl"/>

    <xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>

    <xsl:template match="/CMD_ComponentSpec">
        <xs:schema xmlns:xs="http://www.w3.org/2001/XMLSchema" xmlns:dcr="http://www.isocat.org">
            <xs:element name="CMD">
                <xs:complexType>
                    <xs:sequence>

                        <!--  First produce header elements (description and resources)-->
                        <xsl:call-template name="PrintHeader"/>

                        <!-- Then generate the components -->
                        <xs:element name="Components">
                            <xs:complexType>
                                <xs:sequence>
                                    <!--Start with processing the root component once and then process everything else recursively-->
                                    <xsl:apply-templates select="/CMD_ComponentSpec/CMD_Component"/>
                                </xs:sequence>
                            </xs:complexType>
                        </xs:element>

                        <!-- Generate the footer -->
                    </xs:sequence>
                </xs:complexType>
            </xs:element>
        </xs:schema>
    </xsl:template>

    <!-- convert all components -->
    <xsl:template match="CMD_Component">

        <!-- TODO: maybe there is a more elegant construction than this choose -->
        <xsl:choose>
            <!-- ConceptLink attribute exists -->
            <xsl:when test="@ConceptLink">
                <xs:element name="{@name}" minOccurs="{@CardinalityMin}" maxOccurs="{@CardinalityMax}" dcr:datcat="{@ConceptLink}">
                    <xs:complexType>
                        <xs:sequence>
                            <!-- process all elements at this level -->
                            <xsl:apply-templates select="./CMD_Element"/>
                            <!-- process all components at one level deeper (recursive call) -->
                            <xsl:apply-templates select="./CMD_Component"/>
                        </xs:sequence>
                        <xs:attribute name="ref" type="xs:IDREF"/>
                    </xs:complexType>
                </xs:element>
            </xsl:when>
            <!-- else (there is no ConceptLink attribute) -->
            <xsl:otherwise>
                <xs:element name="{@name}" minOccurs="{@CardinalityMin}" maxOccurs="{@CardinalityMax}">
                    <xs:complexType>
                        <xs:sequence>
                            <!-- process all elements at this level -->
                            <xsl:apply-templates select="./CMD_Element"/>
                            <!-- process all components at one level deeper (recursive call) -->
                            <xsl:apply-templates select="./CMD_Component"/>
                        </xs:sequence>
                        <xs:attribute name="ref" type="xs:IDREF"/>
                    </xs:complexType>
                </xs:element>
            </xsl:otherwise>
        </xsl:choose>

    </xsl:template>

    <!-- Rename CMD_Element and convert its attributes and children -->
    <xsl:template match="CMD_Element">
        <xsl:element name="xs:element">
            <xsl:apply-templates select="@* | node()"/>
        </xsl:element>
    </xsl:template>

    <!-- then convert all ValueScheme elements -->
    <xsl:template match="ValueScheme">
        <xs:simpleType>
            <xs:restriction base="xs:string">
                <xsl:apply-templates select="pattern"/>
                <xsl:apply-templates select="enumeration"/>
            </xs:restriction>
        </xs:simpleType>
    </xsl:template>

    <!-- Convert patterns -->
    <xsl:template match="pattern">
        <xs:pattern value="{self::node()}"/>
    </xsl:template>

    <!-- Convert enumerations -->
    <xsl:template match="enumeration">
        <xsl:for-each select="item">
            <xs:enumeration value="{node()}" dcr:datcat="{@ConceptLink}"/>
        </xsl:for-each>
    </xsl:template>

    <!-- remove empty attributes -->
    <!--<xsl:template match="@*[not(string())]" />-->

    <!--  default action: keep the attributes like they are -->
    <xsl:template match="@*|node()">
        <xsl:copy/>
    </xsl:template>

    <!-- except for those attributes we want to be renamed -->
    <xsl:template match="@CardinalityMin">
        <xsl:attribute name="minOccurs">
            <xsl:value-of select="."/>
        </xsl:attribute>
    </xsl:template>

    <xsl:template match="@CardinalityMax">
        <xsl:attribute name="maxOccurs">
            <xsl:value-of select="."/>
        </xsl:attribute>
    </xsl:template>

    <xsl:template match="@ConceptLink">
        <!-- if attribute is not empty convert it -->
        <xsl:if test="string(.)">
            <xsl:attribute name="dcr:datcat">
                <xsl:value-of select="."/>
            </xsl:attribute>
        </xsl:if>
    </xsl:template>

    <xsl:template match="@ValueScheme">
        <xsl:attribute name="type">
            <xsl:value-of select="concat('xs:',.)"/>
        </xsl:attribute>
    </xsl:template>

</xsl:stylesheet>