source: ISOcat/trunk/mod-ISOcat-interface-rest/representations/dcs2/rng.xsl @ 2029

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="2.0" xmlns:dcif="http://www.isocat.org/ns/dcif" xmlns:dcr="http://www.isocat.org/ns/dcr" xmlns:isocat="http://www.isocat.org/" xmlns:sch="http://purl.oclc.org/dsdl/schematron" xmlns:rng="http://relaxng.org/ns/structure/1.0" exclude-result-prefixes="dcif isocat">
    <xsl:output method="xml" encoding="utf-8" indent="yes"/>
    <xsl:param name="props"/>
    <xsl:variable name="NL" select="system-property('line.separator')"/>
    <xsl:variable name="indent" select="'&#160;&#160;&#160;&#160;'"/>
    <xsl:template match="text()"/>

    <xsl:template match="dcif:dataCategorySelection">
        <rng:grammar datatypeLibrary="http://www.w3.org/2001/XMLSchema-datatypes">
            <xsl:comment>
                <xsl:value-of select="$indent"/>
                <xsl:text>This Relax NG document is mainly a template to be further developed in a full</xsl:text>
                <xsl:value-of select="$NL"/>
                <xsl:value-of select="$indent"/>
                <xsl:text>schema. It's main purpose is to provide dcr:datcat annotation attributes to</xsl:text>
                <xsl:value-of select="$NL"/>
                <xsl:value-of select="$indent"/>
                <xsl:text>maintain the link between the generated elements and values and the used Data</xsl:text>
                <xsl:value-of select="$NL"/>
                <xsl:value-of select="$indent"/>
                <xsl:text>Categories.</xsl:text>
                <xsl:value-of select="$NL"/>
            </xsl:comment>
            <xsl:apply-templates select="dcif:dataCategory"/>
        </rng:grammar>
    </xsl:template>

    <xsl:template match="dcif:dataCategory[@type='container']">
        <xsl:variable name="name" select="./@isocat:identifier"/>
        <xsl:variable name="datcatref" select="./@pid"/>
        <rng:define name="{$name}">
            <rng:element name="{$name}" dcr:datcat="{$datcatref}">
                <xsl:comment>
                    <xsl:value-of select="$indent"/>
                    <xsl:text>Embed (references to) other elements related to container or complex</xsl:text>
                    <xsl:value-of select="$NL"/>
                    <xsl:value-of select="$indent"/>
                    <xsl:text>Data Categories here.</xsl:text>
                    <xsl:value-of select="$NL"/>
                </xsl:comment>
            </rng:element>
        </rng:define>
    </xsl:template>

    <xsl:template match="dcif:dataCategory[@type='complex']">
        <xsl:variable name="name" select="./@isocat:identifier"/>
        <xsl:variable name="datcatref" select="./@pid"/>
        <xsl:variable name="datatype" select="./dcif:conceptualDomain[1]/dcif:dataType"/>
        <rng:define name="{$name}">
            <rng:element name="{$name}" dcr:datcat="{$datcatref}">
                <xsl:choose>
                    <xsl:when test="./@isocat:type eq 'open'">
                        <rng:value>
                            <rng:data type="{$datatype}"/>
                        </rng:value>
                    </xsl:when>
                    <xsl:when test="./@isocat:type eq 'constrained'">
                        <xsl:call-template name="conceptualDomainTemplate"/>
                    </xsl:when>
                    <xsl:when test="./@isocat:type eq 'closed'">
                        <rng:choice>
                            <xsl:for-each-group select="dcif:conceptualDomain/dcif:value[empty(@isocat:suppress) or (@isocat:suppress!='true')]" group-by="@isocat:name">
                                <xsl:for-each select="current-group()">
                                    <xsl:variable name="datcat" select="./@pid"/>
                                    <xsl:choose>
                                        <xsl:when test="position() eq 1">
                                            <rng:value dcr:datcat="{$datcat}">
                                                <xsl:value-of select="current-grouping-key()"/>
                                            </rng:value>
                                        </xsl:when>
                                        <xsl:otherwise>
                                            <xsl:value-of select="$NL"/>
                                            <xsl:comment>
                                                <xsl:text>&lt;rng:value dcr:datcat="</xsl:text>
                                                <xsl:value-of select="$datcat"/>
                                                <xsl:text>"></xsl:text>
                                                <xsl:value-of select="current-grouping-key()"/>
                                                <xsl:text>&lt;/rng:value></xsl:text>
                                            </xsl:comment>
                                            <xsl:value-of select="$NL"/>
                                        </xsl:otherwise>
                                    </xsl:choose>
                                </xsl:for-each>
                            </xsl:for-each-group>
                        </rng:choice>
                    </xsl:when>
                </xsl:choose>
            </rng:element>
        </rng:define>
    </xsl:template>

    <!-- skip simple DCs as they are handled through the value domain of a closed DC -->
    <xsl:template match="dcif:dataCategory[@type='simple']"/>
        
    <xsl:template match="*" mode="nonscopy">
        <xsl:element name="{local-name(.)}" namespace="{namespace-uri()}">
            <xsl:copy-of select="@*"/>
            <xsl:apply-templates mode="nonscopy"/>
        </xsl:element>
    </xsl:template>

    <xsl:template name="conceptualDomainTemplate">
        <xsl:choose>
            <xsl:when test="dcif:conceptualDomain[dcif:ruleType='Relax NG datatype parameter']">
                <xsl:variable name="datatype" select="(dcif:conceptualDomain/dcif:dataType)[1]"/>
                <rng:value>
                    <rng:data type="{$datatype}">
                        <xsl:apply-templates select="(dcif:conceptualDomain[dcif:ruleType='Relax NG datatype parameter']/dcif:rule/*)[1]" mode="nonscopy"/>
                    </rng:data>
                </rng:value>
            </xsl:when>
            <xsl:when test="dcif:conceptualDomain[dcif:ruleType='XML Schema regular expression']">
                <xsl:variable name="datatype" select="(dcif:conceptualDomain/dcif:dataType)[1]"/>
                <rng:value>
                    <rng:data type="{$datatype}">
                        <rng:param name="pattern">
                            <xsl:value-of select="(dcif:conceptualDomain[dcif:ruleType='XML Schema regular expression']/dcif:rule)[1]"/>
                        </rng:param>
                    </rng:data>
                </rng:value>
            </xsl:when>
            <xsl:when test="dcif:conceptualDomain[dcif:ruleType='Schematron rule']">
                <xsl:variable name="datatype" select="(dcif:conceptualDomain/dcif:dataType)[1]"/>
                <xsl:attribute name="type" select="concat('xs:',$datatype)"/>
                <xsl:apply-templates select="(dcif:conceptualDomain[dcif:ruleType='Schematron rule']/dcif:rule/*)[1]" mode="nonscopy"/>
            </xsl:when>
            <xsl:otherwise>
                <xsl:variable name="datatype" select="(dcif:conceptualDomain/dcif:dataType)[1]"/>
                <rng:value>
                    <rng:data type="{$datatype}"/>
                </rng:value>
            </xsl:otherwise>
        </xsl:choose>
    </xsl:template>
</xsl:stylesheet>