source: cats/ISOcat/trunk/mod-ISOcat-interface-rest/representations/dcs2/xsd.xsl @ 2330

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="2.0"
    xmlns:dcif="http://www.isocat.org/ns/dcif" xmlns:dcr="http://www.isocat.org/ns/dcr"
    xmlns:isocat="http://www.isocat.org/" xmlns:xs="http://www.w3.org/2001/XMLSchema"
    xmlns:sch="http://purl.oclc.org/dsdl/schematron" exclude-result-prefixes="dcif isocat">
    <xsl:output method="xml" encoding="utf-8" indent="yes"/>
    <xsl:param name="props"/>
    <xsl:variable name="NL" select="system-property('line.separator')"/>
    <xsl:variable name="indent" select="'&#160;&#160;&#160;&#160;'"/>
    <xsl:template match="text()"/>

    <xsl:template match="dcif:dataCategorySelection">
        <xs:schema>
            <xsl:comment>
                <xsl:value-of select="$indent"/>
                <xsl:text>This XML Schema document is mainly a template to be further developed in a full</xsl:text>
                <xsl:value-of select="$NL"/>
                <xsl:value-of select="$indent"/>
                <xsl:text>schema. It's main purpose is to provide dcr:datcat annotation attributes to</xsl:text>
                <xsl:value-of select="$NL"/>
                <xsl:value-of select="$indent"/>
                <xsl:text>maintain the link between the generated elements and values and the used Data</xsl:text>
                <xsl:value-of select="$NL"/>
                <xsl:value-of select="$indent"/>
                <xsl:text>Categories.</xsl:text>
                <xsl:value-of select="$NL"/>
            </xsl:comment>
            <xsl:apply-templates select="dcif:dataCategory"/>
        </xs:schema>
    </xsl:template>

    <xsl:template match="dcif:dataCategory[@type='container']">
        <xsl:variable name="name" select="./@isocat:identifier"/>
        <xsl:variable name="datcatref" select="./@pid"/>
        <xs:element name="{$name}" dcr:datcat="{$datcatref}">
            <xs:complexType>
                <xsl:comment>
                    <xsl:value-of select="$indent"/>
                    <xsl:text>Embed (references to) other elements related to container or complex</xsl:text>
                    <xsl:value-of select="$NL"/>
                    <xsl:value-of select="$indent"/>
                    <xsl:text>Data Categories here.</xsl:text>
                    <xsl:value-of select="$NL"/>
                </xsl:comment>
            </xs:complexType>
        </xs:element>
    </xsl:template>
    
    <xsl:template match="dcif:dataCategory[@type='complex']">
        <xsl:variable name="name" select="./@isocat:identifier"/>
        <xsl:variable name="datcatref" select="./@pid"/>
        <xsl:variable name="datatype" select="./dcif:conceptualDomain[1]/dcif:dataType"/>
        <xs:element name="{$name}" dcr:datcat="{$datcatref}">
            <xsl:choose>
                <xsl:when test="./@isocat:type eq 'open'">
                    <xsl:attribute name="type" select="concat('xs:',$datatype)"/>
                </xsl:when>
                <xsl:when test="./@isocat:type eq 'constrained'">
                    <xsl:call-template name="conceptualDomainTemplate"/>
                </xsl:when>
                <xsl:when test="./@isocat:type eq 'closed'">
                    <xs:simpleType>
                        <xs:restriction base="xs:{$datatype}">
                            <xsl:for-each-group select="dcif:conceptualDomain/dcif:value[empty(@isocat:suppress) or (@isocat:suppress!='true')]" group-by="@isocat:name">
                                <xsl:for-each select="current-group()">
                                    <xsl:variable name="datcat" select="./@pid"/>
                                    <xsl:variable name="groupname"
                                        select="current-grouping-key()"/>
                                    <xsl:choose>
                                        <xsl:when test="position() eq 1">
                                            <xs:enumeration value="{$groupname}"
                                              dcr:datcat="{$datcat}"/>
                                        </xsl:when>
                                        <xsl:otherwise>
                                            <xsl:value-of select="$NL"/>
                                            <xsl:comment>
                                              <xsl:text>&lt;xs:enumeration value="</xsl:text>
                                              <xsl:value-of select="$groupname"/>
                                              <xsl:text>" dcr:datcat="</xsl:text>
                                              <xsl:value-of select="$datcat"/>
                                              <xsl:text>"/></xsl:text>
                                            </xsl:comment>
                                            <xsl:value-of select="$NL"/>
                                        </xsl:otherwise>
                                    </xsl:choose>
                                </xsl:for-each>
                            </xsl:for-each-group>
                        </xs:restriction>
                    </xs:simpleType>
                </xsl:when>
            </xsl:choose>
        </xs:element>
    </xsl:template>
    
    <!-- skip simple DCs as they are handled through the value domain of a closed DC -->
    <xsl:template match="dcif:dataCategory[@type='simple']"/>

    <xsl:template name="conceptualDomainTemplate">
        <xsl:choose>
            <xsl:when test="dcif:conceptualDomain[dcif:ruleType='XML Schema facet']">
                <xsl:variable name="datatype" select="(dcif:conceptualDomain/dcif:dataType)[1]"/>
                <xs:simpleType>
                    <xs:restriction base="xs:{$datatype}">
                        <xsl:copy-of copy-namespaces="no"
                            select="(dcif:conceptualDomain[dcif:ruleType='XML Schema facet']/dcif:rule/*)[1]"/>
                    </xs:restriction>
                </xs:simpleType>
            </xsl:when>
            <xsl:when test="dcif:conceptualDomain[dcif:ruleType='XML Schema regular expression']">
                <xsl:variable name="datatype" select="(dcif:conceptualDomain/dcif:dataType)[1]"/>
                <xs:simpleType>
                    <xs:restriction base="xs:{$datatype}">
                        <xsl:variable name="pattern"
                            select="(dcif:conceptualDomain[dcif:ruleType='XML Schema regular expression']/dcif:rule)[1]"/>
                        <xs:pattern value="{$pattern}"/>
                    </xs:restriction>
                </xs:simpleType>
            </xsl:when>
            <xsl:when test="dcif:conceptualDomain[dcif:ruleType='Schematron rule']">
                <xsl:variable name="datatype" select="(dcif:conceptualDomain/dcif:dataType)[1]"/>
                <xsl:attribute name="type" select="concat('xs:',$datatype)"/>
                <xsl:copy-of copy-namespaces="no"
                    select="(dcif:conceptualDomain[dcif:ruleType='Schematron rule']/dcif:rule/*)[1]"/>
            </xsl:when>
            <xsl:when test="dcif:conceptualDomain[dcif:ruleType='SCHEMAcat reference']">
                <xsl:variable name="datatype" select="(dcif:conceptualDomain/dcif:dataType)[1]"/>
                <xsl:attribute name="type" select="concat('xs:',$datatype)"/>
                <xs:annotation>
                    <xs:appinfo>
                        <xsl:copy-of copy-namespaces="no"
                            select="(dcif:conceptualDomain[dcif:ruleType='SCHEMAcat reference']/dcif:rule/*)[1]"/>
                    </xs:appinfo>
                </xs:annotation>
            </xsl:when>
            <xsl:otherwise>
                <xsl:variable name="datatype" select="(dcif:conceptualDomain/dcif:dataType)[1]"/>
                <xsl:attribute name="type" select="concat('xs:',$datatype)"/>
            </xsl:otherwise>
        </xsl:choose>
    </xsl:template>
</xsl:stylesheet>