Taskforces/FCS/FCS-QL: FCS_QL_2.g4

// 2015-08-03 PFB sample
// Define a grammar for Federated Content Seach Query language (cf. https://trac.clarin.eu/wiki/Taskforces/FCS/FCS-QL)
//
// 0. Install Java (version 1.6 or higher)
//
// 1. Download antlr version 4.5:
//      $ cd /usr/local/lib
//      $ curl -O http://www.antlr.org/download/antlr-4.5-complete.jar
//    Or just download in browser from website:
//      http://www.antlr.org/download.html
//      and put it somewhere rational like /usr/local/lib.
// 
// 2. Add antlr-4.5-complete.jar to your CLASSPATH:
//      $ export CLASSPATH=".:/usr/local/lib/antlr-4.5-complete.jar:$CLASSPATH"
//      It's also a good idea to put this in your .bash_profile or whatever your startup script is.
// 
// 3. Create aliases for the ANTLR Tool, and TestRig.
//      $ alias antlr4='java -Xmx500M -cp "/usr/local/lib/antlr-4.5-complete.jar:$CLASSPATH" org.antlr.v4.Tool'
//      $ alias grun='java org.antlr.v4.runtime.misc.TestRig'
//
// 4. Compile your grammar:
//      antlr4 FCS-QL.g4
//      javac FCS-QL*.java
//
// 5. Run your parser:  // -gui => interactive tree diagram output; -tree => bracketed textual output
//      grun FCS_QL query -gui < test_00004.in
//
// TO DO: handle full unicode (rules [27] [29] [30])
// TO DO: test alternatives

grammar FCS_QL_2 ;

//--- [1]
query :
      main_query within_part?
    ;

//--- [2v2] no left recursion or ambiguity
main_query :
      simple_query
    | simple_query '|' main_query       // 'or'
    | simple_query main_query           // sequence
    | simple_query quantifier           // quantification
    ;

//--- [3v2]
simple_query :
      '(' main_query ')'
    | implicit_query
    | segment_query
    ;

//--- [4]
implicit_query :
      flagged_regexp
    ;

//--- [5v2] 'expression no longer optional
segment_query :
      '[' expression ']'
    ;

//--- [6]
within_part :
       simple_within_part
    ;

//--- [7]
simple_within_part:
      'within' simple_within_scope
    ;

//--- [8]
simple_within_scope :
      'sentence'
    | 's'
    | 'utterance'
    | 'u'
    | 'pararaph'
    | 'p'
    | 'turn'
    | 't'
    | 'text'
    | 'session'
    ; 

//--- [9]..[10]
// not present in spec

//--- [11v2]
expression :
      basic_expression
    | basic_expression '|' expression   // or
    | basic_expression '&' expression   // and
    ;

//--- [12v2]
basic_expression :
      '(' expression ')'        // grouping
    | '!' expression            // not
    | attribute operator flagged_regexp
    ;

//-- [13]
operator :
      ISOP      // equals
    | ISNTOP    // not eqals
    ;

//--- 13A: terminal, split off from 13
ISOP :
      '='
    ;

//--- 13B: terminal, split off from 13
ISNTOP :
      '!='
    ;

//--- [14]
quantifier :
      '+'                               // one or more
    | '*'                               // zero or more
    | '?'                               // zero or one
    | '{' integer '}'                   // exactly 'integer' times
    | '{' integer? ',' integer '}'      // optional min - max
    | '{' integer ',' integer? '}'      // min - optional max
    ;

//--- [15]
flagged_regexp :
      regexp
    | regexp '/' REGEXP_FLAG+
    ;

//--- [16v2]
REGEXP_FLAG :
      [CIcdli]+
    ;

//--- [17]
regexp :
      quoted_string
    ;

//--- [18]
attribute :
      simple_attribute
    | qualified_attribute
    ;

//--- [19]
simple_attribute :
      ATTRIBUTE ;

ATTRIBUTE:
      [A-Za-z][A-Za-z0-9_]*
    ;

//--- [20]
qualified_attribute :
      ATTRIBUTE ':' ATTRIBUTE
    ;

//--- [21]
// identifier : replaced by ATTRIBUTE

//--- [22]
// identifier_char : replaced by ATTRIBUTE

//--- [23]
// not available in spec

//--- [24]
integer :
      DIGITS ;

//--- [25]
// not available in spec

//--- [26]
quoted_string :
      'qstr'
    | STRING_LITERAL
    ;

//--- [26A] adapted to something antlr will process correctly
STRING_LITERAL : '"' (~('"' | '\\' | '\r' | '\n') | '\\' ('"' | '\\'))* '"';

DIGITS :
    [0-9]+ ;

//--- [28]
WS : [ \t\n\r]+ -> skip ;