source: MDRepository/trunk/xquery/group.xsl @ 1045

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
 xmlns:xs="http://www.w3.org/2001/XMLSchema"
version="2.0">

<!--
two tasks (in separate calls, managed by $mode-param):
1. produces an index by grouping content        
2. selects a subsequence of the produced content
-->

<xsl:param name="mode" select="'aggregate'" />
<xsl:param name="sort" select="'text'" />
<xsl:param name="filter" select="''" />
<xsl:param name="filter-mode" select="if (ends-with($filter,'*')) then 'starts-with' else 'contains'" /> <!-- contains, starts-with -->
<xsl:param name="start-item" select="100" />
<xsl:param name="max-items" select="100" />

    <xsl:template match="/">
<!--            <Terms>
                        <params mode="{$mode}" sort="{$sort}"  /> -->
                <xsl:choose>
                        <xsl:when test="$mode='subsequence'" >
                                <xsl:apply-templates mode="subsequence" />
                        </xsl:when>
                        <xsl:otherwise>
                                <xsl:apply-templates />
                        </xsl:otherwise>
                </xsl:choose>
    </xsl:template>

    <xsl:template match="Term">
                <xsl:variable name="nodes" select="*" />
                <xsl:variable name="count-text" select="count($nodes/text()[.!=''])" />
                <xsl:variable name="distinct-text-count" select="count(distinct-values($nodes/text()))" />

                <Term name="{*[1]/name()}" count="{count($nodes)}" count_text="{$count-text}"  count_distinct_text="{$distinct-text-count}">
                        <xsl:copy-of select="@*" />
            <xsl:for-each-group select="*" group-by="text()">
                <v key="{text()}" count="{count(current-group())}"/>
            </xsl:for-each-group>
        </Term>
    </xsl:template>

    <xsl:template match="Term" mode="subsequence">

        <!-- this may be potentially expensive and we may need to store the index already sorted (which is the normal/sane way to do!) -->
                <xsl:variable name="filtered" select="*[if ($filter!='') then 
                                                                                                                if ($filter-mode='starts-with') then starts-with(@key,substring-before($filter,'*'))
                                                                                                                                        else contains(@key, $filter)
                                                                                                                else true()]" />
                <xsl:variable name="ordered" >
                        <xsl:choose>
                        <xsl:when test="$sort='size'" > 
                                <xsl:for-each select="$filtered" >
                                        <xsl:sort select="@count" data-type="number" order="descending" />
                                        <xsl:copy-of select="." />
                                </xsl:for-each>
                        </xsl:when>
                        <xsl:otherwise>
                                <xsl:for-each select="$filtered" >
                                        <xsl:sort select="@key" data-type="text" order="ascending" />                                   
                                        <xsl:copy-of select="."/>
                                </xsl:for-each>
                        </xsl:otherwise>
                        </xsl:choose>
                </xsl:variable>

<!--            <xsl:variable name="count-items" select="count($filtered)" />-->
                <xsl:copy>
                        <xsl:copy-of select="@*" />
<!--                    <xsl:value-of select="count($ordered/*)" /> -->
<!--                    <xsl:attribute name="count_items" select="if (xs:integer($count-items) &gt; xs:integer($max-items)) then $max-items else $count-items" /> -->
                                <xsl:apply-templates select="$ordered/*[xs:integer(position()) &gt;= xs:integer($start-item) and (xs:integer(position()) &lt; (xs:integer($start-item) + xs:integer($max-items)))]" />
                </xsl:copy>
    </xsl:template>

        <xsl:template match="v" >
                <xsl:copy>
                        <xsl:copy-of select="@*" />
                        <xsl:attribute name="pos" select="position()" />
                </xsl:copy>
        </xsl:template>

</xsl:stylesheet>