source: MDService2/trunk/MDService2/src/xsl/mdinst2view.xsl @ 1064

<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet
  version="2.0"
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  xmlns:xs="http://www.w3.org/2001/XMLSchema"
 xmlns:my="myFunctions"  
>
<!-- 
<purpose> generate a generic html view of a CMDI-instance.</purpose>
<params>
<param name=""></param>
</params>
<history>
        <change on="2009-12-31" type="created" by="vr">from cmd2view.xsl (no adaptation yet)</change>   
        <change on="2010-03-20" type="changed" by="vr">only started to rework</change>  
        <change on="2010-03-26" type="changed" by="vr">include cmd_commons.xsl</change> 
        <change on="2010-07-11" type="changed" by="vr">integrate into MDService</change>
</history>
-->
    
<xsl:output method="html" />

<xsl:include href="cmd_commons.xsl"/>

<xsl:param name="base_uri" select="'file:///C:/Users/master/3lingua/clarin/CMDI/data/C4_cmds/'" />    

<!--   <xsl:param name="mode" select="'htmldiv'" /> -->
<xsl:param name="title" />
<xsl:param name="inner_title" >
<!-- Gather just first title/name or something --> 
                <xsl:variable name="titles">                                                                     
                                        <xsl:choose>
                                        <xsl:when test="exists(//Title/text())">
                                                        <xsl:copy-of select="//Title" />
                                        </xsl:when>
                                        <xsl:when test="exists(//title/text())">
                                                        <xsl:copy-of select="//title" />
                                        </xsl:when>
                                        <xsl:otherwise>
                                                        <xsl:copy-of select="(//Name|//name)" />
                                        </xsl:otherwise>
                                </xsl:choose>
                </xsl:variable>
                <!--<xsl:value-of select="count($titles)" /> -->
                <xsl:value-of select="$titles/*[1]" />                  
</xsl:param>

<xsl:template name="continue-root" >

        <div class="mdrecord-detail" >
                <xsl:choose>
                        <xsl:when test="contains($format,'htmlpage')">
                                <h3><xsl:value-of select="$inner_title" /></h3>
                        </xsl:when>     
                        <xsl:otherwise>
                                <span class="inner_title"><xsl:attribute name="value"><xsl:value-of select="$inner_title"/></xsl:attribute>
                                </span>
                        </xsl:otherwise>
                </xsl:choose>
                
         <!--
         <span class="label">MDRecord View: </span>
                <div class="box_heading hilight"><xsl:value-of select="$inner_title"/></div> 
          -->
        
                <xsl:apply-templates select=".//IsPartOfList" />
                <xsl:apply-templates select=".//ResourceProxyList" />
                <xsl:apply-templates select=".//Components/*" mode="format-xmlelem" />
        </div>  
</xsl:template> 
        
<xsl:template match="IsPartOfList" >
        <div class="ispartof-list"><span class="label">IsPartOf:</span>
                <xsl:apply-templates select=".//IsPartOf" />
        </div>
</xsl:template> 

<xsl:template match="IsPartOf" >
        <a class="internal" href="{concat($default_prefix, my:encodePID(.))}"><xsl:value-of select="." /></a>,
</xsl:template> 

        
<xsl:template match="ResourceProxyList" >
                <xsl:choose>
                        <xsl:when test="count(ResourceProxy) &gt; 1"> 
                                <div class="resource-links">
                                        <span class="detail-caller">
                                                <span class="cmd cmd_up" ></span><span class="label" >references </span><xsl:value-of select="count(ResourceProxy[ResourceType='Metadata'])" /> <span class="label" > MDRecords, </span> 
                                                                        <xsl:value-of select="count(ResourceProxy[ResourceType='Resource'])" /> <span class="label" > Resources</span>
                                        </span>                                 
                                        <ul class="detail"> 
                                                <xsl:if test="count(ResourceProxy) &gt; $resourceref_limit" >
                                                        <span class="label" >showing first </span> <xsl:value-of select="$resourceref_limit" /> <span class="label" > references. </span> 
                                                        <s><a href="{concat($default_prefix, my:encodePID(./ancestor::CMD/Header/MdSelfLink))}">see more</a></s>                                                        
                                                </xsl:if>
                                                <xsl:apply-templates select="ResourceProxy[position() &lt; $resourceref_limit]" />
                                        </ul>
                                </div>
                        </xsl:when>
                        <xsl:otherwise>
                                <ul>
                                        <xsl:apply-templates />
                                </ul>                   
                        </xsl:otherwise>
                </xsl:choose>
                
</xsl:template> 
        
        <xsl:template match="ResourceProxy" >
        
                        <xsl:variable name="href" >                                              
                                <xsl:choose>
                                        <xsl:when test="ResourceType='Resource'">
                                                        <xsl:value-of select="ResourceRef" />
                                        </xsl:when>
                                        <xsl:otherwise>
                                                        <xsl:value-of select="concat($default_prefix, my:encodePID(ResourceRef))" />
                                        </xsl:otherwise>
                                </xsl:choose>                           
                        </xsl:variable>
                        
                        <xsl:variable name="class" select=" if (ResourceType='Resource') then 'external' else 'internal'" />
                        
                <li><span class="label" ><xsl:value-of select="ResourceType" />: </span> 
                                <a class="{$class}" href="{$href}" target="_blank" >
                                                <xsl:value-of select="ResourceRef" />
                                </a>
                </li>
        </xsl:template> 

</xsl:stylesheet>