source: RELcat/trunk/mod-RELcat-interface-rest/representations/SRX-spo-RDF.xsl @ 2029

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    version="2.0"
    xmlns:sparql="http://www.w3.org/2005/sparql-results#"
    xmlns:rdf="http://www.w3.org/1999/02/22-rdf-syntax-ns#"
>
    
    <xsl:template match="text()"/>
    
    <xsl:template match="/sparql:sparql">
        <rdf:RDF>
            <xsl:apply-templates/>
        </rdf:RDF>
    </xsl:template>
    
    <xsl:template match="sparql:result[exists(sparql:binding[@name='s']) and exists(sparql:binding[@name='p']) and exists(sparql:binding[@name='o'])]">
        <xsl:variable name="s" select="sparql:binding[@name='s']/sparql:uri"/>
        <xsl:variable name="p" select="sparql:binding[@name='p']/sparql:uri"/>
        <xsl:variable name="o" select="sparql:binding[@name='o']/sparql:uri"/>
        <rdf:Description rdf:about="{$s}">
            <xsl:choose>
                <xsl:when test="contains($p,'#')">
                    <xsl:element namespace="{substring-before($p,'#')}#" name="{substring-after($p,'#')}">
                        <xsl:attribute name="rdf:resource" select="$o"/>
                    </xsl:element>
                </xsl:when>
                <xsl:when test="replace($p,'.*/','')!=''">
                    <xsl:element namespace="{replace($p,'/[^/]*?$','')}/" name="{replace($p,'.*/','')}">
                        <xsl:attribute name="rdf:resource" select="$o"/>
                    </xsl:element>
                </xsl:when>
                <xsl:otherwise>
                    <xsl:message terminate="yes">
                        <xsl:text>ERR: don't know how to transform the URI[</xsl:text>
                        <xsl:value-of select="$p"/>
                        <xsl:text>] into a valid QName!</xsl:text>
                    </xsl:message>
                </xsl:otherwise>
            </xsl:choose>
        </rdf:Description> 
    </xsl:template>
    
</xsl:stylesheet>