source: cats/ISOcat/trunk/mod-ISOcat-interface-gi/interface/JSXAPPS/ISOcat/xsl/SubmissionCheck2HTML.xsl @ 2893

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">

    <xsl:template match="text()"/>
    
    <xsl:template match="cr">
        <div>
            <xsl:choose>
                <xsl:when test="@check='valid'">
                    <p>This is a <b>valid</b> submission.</p>
                </xsl:when>
                <xsl:when test="@check='invalid'">
                    <p>This submission is <b>invalid</b>. The following problems were found:</p>
                    <ol>
                        <xsl:apply-templates/>
                    </ol>
                </xsl:when>
            </xsl:choose>
        </div>
    </xsl:template>
    
    <xsl:template match="log[@check='invalid']">
        <li>There is no description.</li>
    </xsl:template>
    
    <xsl:template match="td[count(tdg[@check='valid'])=0]">
        <li>There is no TDG which can (or is allowed to) manage all the selected data categories.</li>
        <xsl:if test="tdg[@check='invalid']">
            <ol>
                <xsl:apply-templates/>
            </ol>
        </xsl:if>
    </xsl:template>
        
    <xsl:template match="group[@check='invalid']">
        <xsl:for-each select="error|warning">
            <li>
                <xsl:value-of select="."/>
            </li>            
        </xsl:for-each>
    </xsl:template>
    
    <xsl:template match="tdg[@check='invalid']/profile">
        <li>
            <xsl:text>The following data categories aren't a member of the profile </xsl:text>
            <xsl:value-of select="@name"/>
            <xsl:text> managed by the </xsl:text>
            <xsl:value-of select="parent::tdg/@name"/>
            <xsl:text> TDG:</xsl:text>
            <ol>
                <xsl:for-each select="dc">
                    <xsl:variable name="dc" select="current()"/>
                    <li>
                        <xsl:text>/</xsl:text>
                        <i>
                            <xsl:value-of select="/cr/dcs/dc[@ref=$dc/@ref]/identifier"/>
                        </i>
                        <xsl:text>/</xsl:text>
                    </li>
                </xsl:for-each>
            </ol>
        </li>
    </xsl:template>
    
    <xsl:template match="dcs/dc[.//error]">
        <li>
            <xsl:text>The data category </xsl:text> 
            <xsl:text>/</xsl:text>
            <i>
                <xsl:value-of select="identifier"/>
            </i>
            <xsl:text>/</xsl:text>
            <xsl:text> has the following issues:</xsl:text>
            <ol>
                <xsl:for-each select=".//error">
                    <li>
                        <xsl:value-of select="current()"/>
                    </li>
                </xsl:for-each>
            </ol>
        </li>
    </xsl:template>
</xsl:stylesheet>