source: cats/ISOcat/trunk/mod-ISOcat-interface-rest/representations/atom/DC-history.xsl @ 2912

<?xml version="1.0"?>
<xsl:stylesheet
  version="2.0"
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  xmlns:xs="http://www.w3.org/2001/XMLSchema"
  xmlns:isocat="http://www.isocat.org/"
  xmlns:dcr="http://www.isocat.org/ns/dcr"
  xmlns:dcif="http://www.isocat.org/ns/dcif"
  xmlns:atom="http://www.w3.org/2005/Atom"
>

        <xsl:output method="xml" encoding="utf-8"/>

        <xsl:param name="props"/>
        
        <xsl:template match="text()"/>
        
        <xsl:function name="isocat:rest">
                <xsl:param name="node"/>
                <xsl:value-of select="$props//site"/>
                <xsl:text>rest/dc/</xsl:text>
                <xsl:value-of select="$node/(@id|@dc|@ref)"/>
        </xsl:function>

        <xsl:function name="isocat:link">
                <xsl:param name="node"/>
                <span>
                        <xsl:text>/</xsl:text>
                        <a href="{isocat:rest($node)}">
                                <xsl:choose>
                                        <xsl:when test="exists($node/@identifier)">
                                                <xsl:value-of select="$node/@identifier"/>
                                        </xsl:when>
                                        <xsl:otherwise>
                                                <xsl:value-of select="isocat:rest($node)"/>
                                        </xsl:otherwise>
                                </xsl:choose>
                        </a>
                        <xsl:text>/</xsl:text>
                        <xsl:if test="exists($node/@name) and ($node/@name!=$node/@identifier)">
                                <xsl:text> (</xsl:text>
                                <xsl:value-of select="$node/@name"/>
                                <xsl:text>)</xsl:text>
                        </xsl:if>
                </span>
        </xsl:function>

        <xsl:function name="isocat:title">
                <xsl:param name="node"/>
                <xsl:text>History of </xsl:text>
                <xsl:value-of select="isocat:link($node)"/>
                <xsl:text> - </xsl:text>
                <xsl:value-of select="$node/@version"/>
        </xsl:function>
        
        <xsl:function name="isocat:timestamp">
                <xsl:param name="ts"/>
                <xsl:sequence select="replace($ts,'\..*','')"/>
        </xsl:function>
        
        <xsl:template match="change">
                <atom:entry>
                        <atom:id>
                                <xsl:value-of select="/history/dc/@pid"/>
                                <xsl:text>/history#c</xsl:text>
                                <xsl:value-of select="@isocat:id"/>
                        </atom:id>
                        <atom:link rel="alternate" type="text/html">
                                <xsl:attribute name="href">
                                        <xsl:value-of select="isocat:rest(/history/dc)"/>
                                        <xsl:text>/history#c</xsl:text>
                                        <xsl:value-of select="@isocat:id"/>
                                </xsl:attribute>
                        </atom:link>
                        <atom:title>
                                <xsl:text>Change by </xsl:text>
                                <xsl:value-of select="if (normalize-space(user/name)!='') then (user/name) else ('unknown')"/>
                                <xsl:text> at </xsl:text>
                                <xsl:value-of select="isocat:timestamp(@timestamp)"/>
                        </atom:title>
                        <atom:author>
                                <atom:name>
                                        <xsl:value-of select="if (normalize-space(user/name)!='') then (user/name) else ('unknown')"/>
                                </atom:name>
                        </atom:author>
                        <atom:updated>
                                <xsl:value-of select="isocat:timestamp(@timestamp)"/>
                        </atom:updated>
                        <atom:content type="text">
                                <xsl:value-of select="description"/>
                        </atom:content>
                </atom:entry>
        </xsl:template>
        
        <xsl:template match="/history">
                <xsl:variable name="title" select="isocat:title(dc)"/>
                <atom:feed>
                        <atom:id>
                                <xsl:value-of select="dc/@pid"/>
                        </atom:id>
                        <atom:title type="text">
                                <xsl:value-of select="$title"/>
                        </atom:title>
                        <atom:published>
                                <xsl:value-of select="isocat:timestamp((change)[last()]/@timestamp)"/>
                        </atom:published>
                        <xsl:if test="count(change) gt 1">
                                <atom:updated>
                                        <xsl:value-of select="isocat:timestamp((change)[1]/@timestamp)"/>
                                </atom:updated>
                        </xsl:if>
                        <atom:link rel="self" type="application/atom+xml">
                                <xsl:attribute name="href">
                                        <xsl:value-of select="isocat:rest(dc)"/>
                                        <xsl:text>/history.atom</xsl:text>
                                </xsl:attribute>
                        </atom:link>
                        <atom:link rel="alternate" type="text/html">
                                <xsl:attribute name="href">
                                        <xsl:value-of select="isocat:rest(dc)"/>
                                        <xsl:text>/history</xsl:text>
                                </xsl:attribute>
                        </atom:link>
                        <xsl:apply-templates select="change">
                                <xsl:sort order="descending" select="@isocat:id"/>
                        </xsl:apply-templates>
                </atom:feed>
        </xsl:template>

</xsl:stylesheet>