source: cats/ISOcat/trunk/mod-ISOcat-interface-rest/representations/html/DC-history.xsl @ 2912

<?xml version="1.0"?>
<xsl:stylesheet
  version="2.0"
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  xmlns:xs="http://www.w3.org/2001/XMLSchema"
  xmlns:isocat="http://www.isocat.org/"
  xmlns:dcr="http://www.isocat.org/ns/dcr"
  xmlns:dcif="http://www.isocat.org/ns/dcif"
>

        <!--
        don't use the xhtml output method,
        NK (?) will pretty print it during
        serialization and break the layout
        -->
        <xsl:output method="xml" encoding="utf-8"/>

        <xsl:param name="props"/>
        
        <xsl:template match="text()"/>
        
        <xsl:function name="isocat:pid">
                <xsl:param name="node"/>
                <xsl:value-of select="$props//site"/>
                <xsl:text>rest/dc/</xsl:text>
                <xsl:value-of select="$node/(@id|@dc|@ref)"/>
        </xsl:function>

        <xsl:function name="isocat:link">
                <xsl:param name="node"/>
                <span>
                        <xsl:text>/</xsl:text>
                        <a href="{isocat:pid($node)}">
                                <xsl:choose>
                                        <xsl:when test="exists($node/@identifier)">
                                                <xsl:value-of select="$node/@identifier"/>
                                        </xsl:when>
                                        <xsl:otherwise>
                                                <xsl:value-of select="isocat:pid($node)"/>
                                        </xsl:otherwise>
                                </xsl:choose>
                        </a>
                        <xsl:text>/</xsl:text>
                        <xsl:if test="exists($node/@name) and ($node/@name!=$node/@identifier)">
                                <xsl:text> (</xsl:text>
                                <xsl:value-of select="$node/@name"/>
                                <xsl:text>)</xsl:text>
                        </xsl:if>
                </span>
        </xsl:function>
        
        <xsl:function name="isocat:timestamp">
                <xsl:param name="ts"/>
                <xsl:sequence select="replace($ts,'\..*','')"/>
        </xsl:function>

        <xsl:template match="change">
                <dt>
                        <a name="c{@isocat:id}">
                                <xsl:value-of select="isocat:timestamp(@timestamp)"/>
                                <xsl:text> - </xsl:text>
                                <xsl:choose>
                                        <xsl:when test="exists(user/name)">
                                                <xsl:value-of select="user/name"/>
                                        </xsl:when>
                                        <xsl:otherwise>
                                                <i>unknown</i>
                                        </xsl:otherwise>
                                </xsl:choose>
                        </a>
                </dt>
                <dd>
                        <xsl:choose>
                                <xsl:when test="normalize-space(description)">
                                        <xsl:value-of select="description"/>
                                </xsl:when>
                                <xsl:otherwise>
                                        <i>no description of the change</i>
                                </xsl:otherwise>
                        </xsl:choose>
                </dd>
        </xsl:template>
        
        <xsl:function name="isocat:title">
                <xsl:param name="node"/>
                <span>
                        <xsl:text>History of </xsl:text>
                        <xsl:copy-of select="isocat:link($node)"/>
                        <xsl:text> - </xsl:text>
                        <xsl:value-of select="$node/@version"/>
                </span>
        </xsl:function>
        
        <xsl:template match="/history">
                <xsl:variable name="title" select="isocat:title(dc)"/>
                <html>
                        <head>
                                <xsl:if test="exists($title) and (normalize-space(string($title))!='')">
                                        <title>
                                                <xsl:value-of select="string($title)"/>
                                        </title>
                                </xsl:if>
                                <link rel="stylesheet" href="{$props//site}interface/JSXAPPS/ISOcat/css/style.css" type="text/css"/>
                        </head>
                        <body>
                                <div class="title">
                                        <xsl:copy-of select="$title"/>
                                </div>
                                <div class="main">
                                        <xsl:choose>
                                                <xsl:when test="exists(change)">
                                                        <dl>
                                                                <xsl:apply-templates/>
                                                        </dl>
                                                </xsl:when>
                                                <xsl:otherwise>
                                                        <xsl:text>There is no change history for this data category.</xsl:text>
                                                </xsl:otherwise>
                                        </xsl:choose>
                                </div>
                        </body>
                </html>
        </xsl:template>

</xsl:stylesheet>