source: cats/ISOcat/trunk/mod-ISOcat-interface-rest/representations/html/DCS-check.xsl @ 4895

<?xml version="1.0"?>
<xsl:stylesheet
  version="2.0"
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  xmlns:xs="http://www.w3.org/2001/XMLSchema"
  xmlns:isocat="http://www.isocat.org/"
  xmlns:dcr="http://www.isocat.org/ns/dcr"
  xmlns:dcif="http://www.isocat.org/ns/dcif"
>

        <!--
        don't use the xhtml output method,
        NK (?) will pretty print it during
        serialization and break the layout
        -->
        <xsl:output method="xml" encoding="utf-8"/>

        <xsl:param name="props"/>       
        
        <xsl:template match="text()"/>
        
        <xsl:function name="isocat:dcs-rest">
                <xsl:param name="node"/>
                <xsl:value-of select="$props//site"/>
                <xsl:text>rest/dcs/</xsl:text>
                <xsl:value-of select="$node/(@id|@dcs|@ref)"/>
        </xsl:function>
        
        <xsl:function name="isocat:dc-rest">
                <xsl:param name="node"/>
                <xsl:value-of select="$props//site"/>
                <xsl:text>rest/dc/</xsl:text>
                <xsl:value-of select="$node/@ref"/>
        </xsl:function>

        <xsl:function name="isocat:dc-link">
                <xsl:param name="node"/>
                <span>
                        <xsl:text>/</xsl:text>
                    <i>
                        <a href="{isocat:dc-rest($node)}">
                            <xsl:choose>
                                <xsl:when test="exists($node/identifier)">
                                    <xsl:value-of select="$node/identifier"/>
                                </xsl:when>
                                <xsl:otherwise>
                                    <xsl:value-of select="isocat:dc-rest($node)"/>
                                </xsl:otherwise>
                            </xsl:choose>
                        </a>
                    </i>
                        <xsl:text>/</xsl:text>
                        <xsl:if test="exists($node/name) and ($node/name!=$node/identifier)">
                                <xsl:text> (</xsl:text>
                                <xsl:value-of select="$node/name"/>
                                <xsl:text>)</xsl:text>
                        </xsl:if>
                </span>
        </xsl:function>
        
        <xsl:function name="isocat:dcs-link">
                <xsl:param name="node"/>
                <span>
                        <a href="{isocat:dcs-rest($node)}">
                                <xsl:value-of select="$node/@name"/>
                        </a>
                </span>
        </xsl:function>

        <xsl:function name="isocat:timestamp">
                <xsl:param name="ts"/>
                <xsl:sequence select="replace($ts,'\..*','')"/>
        </xsl:function>
    
    <xsl:template match="fatal|error">
        <div>
            <b>
                <xsl:value-of select="local-name()"/>
            </b>
            <xsl:text>: </xsl:text>
            <xsl:value-of select="."/>
        </div>
    </xsl:template>

    <xsl:template match="warning">
        <div>
            <i>
                <xsl:value-of select="local-name()"/>
            </i>
            <xsl:text>: </xsl:text>
            <xsl:value-of select="."/>
        </div>
    </xsl:template>

    <xsl:template match="dc[exists(checks/*)]">
                <dt>
                        <a name="dc{@isocat:id}">
                                <xsl:copy-of select="isocat:dc-link(.)"/>
                        </a>
                </dt>
                <dd>
                    <xsl:apply-templates select="checks"/>
                </dd>
        </xsl:template>
        
        <xsl:function name="isocat:title">
                <xsl:param name="node"/>
                <span>
                        <xsl:text>Check results of the </xsl:text>
                        <xsl:copy-of select="isocat:dcs-link($node)"/>
                        <xsl:text> Data Category Selection</xsl:text>
                </span>
        </xsl:function>
        
        <xsl:template match="/dcs">
                <xsl:variable name="title" select="isocat:title(.)"/>
                <html>
                        <head>
                                <xsl:if test="exists($title) and (normalize-space(string($title))!='')">
                                        <title>
                                                <xsl:value-of select="string($title)"/>
                                        </title>
                                </xsl:if>
                                <link rel="stylesheet" href="{$props//site}interface/JSXAPPS/ISOcat/css/style.css" type="text/css"/>
                        </head>
                        <body>
                                <div class="title">
                                        <xsl:copy-of select="$title"/>
                                </div>
                                <div class="main">
                                        <dl>
                                                <xsl:apply-templates/>
                                        </dl>
                                </div>
                        </body>
                </html>
        </xsl:template>

</xsl:stylesheet>