source: cats/ISOcat/trunk/mod-ISOcat-interface-rest/representations/html/tdg.xsl @ 3040

<?xml version="1.0"?>
<xsl:stylesheet
  version="2.0"
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  xmlns:xs="http://www.w3.org/2001/XMLSchema"
  xmlns:isocat="http://www.isocat.org/"
  xmlns:dcr="http://www.isocat.org/ns/dcr"
  xmlns:dcif="http://www.isocat.org/ns/dcif"
>

        <xsl:param name="title" select="'default'"/>
        <xsl:param name="body"/>
        <xsl:param name="props"/>
        
        <xsl:template match="text()"/>
        
        <xsl:function name="isocat:title">
                <xsl:param name="node"/>
                <xsl:choose>
                        <xsl:when test="exists($title) and ($title instance of node()) and (normalize-space(string($title))!='default')">
                                <xsl:choose>
                                        <xsl:when test="(normalize-space(string($title))!='') and (normalize-space(string($title))!='none')">
                                                <xsl:sequence select="normalize-space(string($title))"/>
                                        </xsl:when>
                                </xsl:choose>
                        </xsl:when>
                        <xsl:when test="exists($node/self::group[normalize-space(name)!=''])">
                                <xsl:sequence select="concat('Thematic Domain Group: ',normalize-space($node/self::group/name))"/>
                        </xsl:when>
                </xsl:choose>
        </xsl:function>
        
        <xsl:function name="isocat:name">
                <xsl:param name="node"/>
                <xsl:choose>
                        <xsl:when test="exists($node/name) and (normalize-space($node/name)!='')">
                                <xsl:sequence select="normalize-space($node/name)"/>
                        </xsl:when>
                        <xsl:otherwise>
                                <xsl:sequence select="normalize-space($node/login)"/>
                        </xsl:otherwise>
                </xsl:choose>
        </xsl:function>
        
        <xsl:template name="TDG">
                <div class="DC">
                        <table class="DC">
                                <xsl:for-each select="//group">
                                        <xsl:variable name="title" select="isocat:title(.)"/>
                                        <xsl:if test="exists($title) and (normalize-space($title)!='')">
                                                <tr class="DC-title">
                                                        <th colspan="2">
                                                                <xsl:value-of select="isocat:title(.)"/>
                                                        </th>
                                                </tr>
                                        </xsl:if>
                                        <tr class="DC-data">
                                                <td class="DC-data-label">Name</td>
                                                <td class="DC-data-value">
                                                        <xsl:value-of select="name"/>
                                                </td>
                                        </tr>
                                        <tr class="DC-data">
                                                <td class="DC-data-label">Description</td>
                                                <td class="DC-data-value">
                                                        <xsl:for-each select="tokenize(description,'\n')">
                                                                <p>
                                                                        <xsl:value-of select="."/>
                                                                </p>
                                                        </xsl:for-each>
                                                </td>
                                        </tr>
                                        <tr class="DC-data">
                                                <td class="DC-data-label">View</td>
                                                <td class="DC-data-value">
                                                        <a href="{$props//site}interface/index.html?view={name}" target="_self">
                                                                <xsl:text>switch to the TDG specific ISOcat view</xsl:text>
                                                        </a>
                                                        <div>(Note: this will reload the ISOcat UI in your browser and might require you to login again!)</div>
                                                </td>
                                        </tr>
                                        <xsl:if test="exists(forum/@public) or exists(forum/@private)">
                                                <tr class="DC-data">
                                                        <td class="DC-data-label">Forum</td>
                                                        <td class="DC-data-value">
                                                                <xsl:choose>
                                                                        <xsl:when test="exists(forum/@public)">
                                                                                <a href="{$props//forum_site}viewforum.php?f={forum/@public}" target="forum">
                                                                                        <xsl:text>public forum</xsl:text>
                                                                                </a>
                                                                        </xsl:when>
                                                                        <xsl:when test="exists(forum/@private)">
                                                                                <a href="{$props//forum_site}viewforum.php?f={forum/@private}" target="forum">
                                                                                        <xsl:text>private forum</xsl:text>
                                                                                </a>
                                                                        </xsl:when>
                                                                </xsl:choose>
                                                        </td>
                                                </tr>
                                        </xsl:if>
                                        <xsl:if test="exists(status or activity)">
                                                <tr class="DC-data">
                                                        <td colspan="2">&#160;</td>
                                                </tr>
                                                <xsl:if test="exists(status)">
                                                        <tr class="DC-data">
                                                                <td class="DC-data-label">Status</td>
                                                                <td class="DC-data-value">
                                                                        <xsl:value-of select="status"/>
                                                                </td>
                                                        </tr>
                                                </xsl:if>
                                                <xsl:if test="exists(activity)">
                                                        <tr class="DC-data">
                                                                <td class="DC-data-label">Activity</td>
                                                                <td class="DC-data-value">
                                                                        <xsl:value-of select="activity"/>
                                                                </td>
                                                        </tr>
                                                </xsl:if>
                                        </xsl:if>
                                        <xsl:if test="exists(member)">
                                                <tr class="DC-header">
                                                        <th colspan="2" class="DC-header-level-1">Members</th>
                                                </tr>
                                                <xsl:for-each select="member[@status='accepted']">
                                                        <xsl:sort select="@role"/>
                                                        <tr class="DC-data">
                                                                <td class="DC-data-label">
                                                                        <xsl:choose>
                                                                                <xsl:when test="@role='chair'">
                                                                                        <xsl:text>Chair</xsl:text>
                                                                                </xsl:when>
                                                                                <xsl:otherwise>
                                                                                        <xsl:text>Member</xsl:text>
                                                                                </xsl:otherwise>
                                                                        </xsl:choose>
                                                                </td>
                                                                <td class="DC-data-value">
                                                                        <xsl:choose>
                                                                                <xsl:when test="forum">
                                                                                        <a href="{$props//forum_site}ucp.php?mode=login&amp;redirect=./memberlist.php?mode=viewprofile%26u={forum}" target="forum">
                                                                                                <xsl:value-of select="isocat:name(.)"/>
                                                                                        </a>
                                                                                </xsl:when>
                                                                                <xsl:otherwise>
                                                                                        <xsl:value-of select="isocat:name(.)"/>
                                                                                </xsl:otherwise>
                                                                        </xsl:choose>
                                                                        <xsl:if test="exists(organization) and (normalize-space(organization)!='')">
                                                                                <xsl:text> (</xsl:text>
                                                                                <xsl:value-of select="normalize-space(organization)"/>
                                                                                <xsl:text>)</xsl:text>
                                                                        </xsl:if>
                                                                </td>
                                                        </tr>
                                                </xsl:for-each>
                                        </xsl:if>
                                </xsl:for-each>
                        </table>
                </div>
        </xsl:template>

        <xsl:template match="/group" priority="1">
                <xsl:choose>
                        <xsl:when test="normalize-space($body)='true'">
                                <html>
                                        <head>
                                                <xsl:variable name="title" select="isocat:title(.)"/>
                                                <xsl:if test="exists($title) and (normalize-space($title)!='')">
                                                        <title>
                                                                <xsl:value-of select="isocat:title(.)"/>
                                                        </title>
                                                </xsl:if>
                                                <link rel="stylesheet" href="{$props//site}interface/JSXAPPS/ISOcat/css/style.css" type="text/css"/>
                                        </head>
                                        <body>
                                                <xsl:call-template name="TDG"/>
                                        </body>
                                </html>
                        </xsl:when>
                        <xsl:otherwise>
                                <xsl:call-template name="TDG"/>
                        </xsl:otherwise>
                </xsl:choose>
        </xsl:template>

</xsl:stylesheet>