source: cats/shared/urn.org.isocat.sloot/trunk/tools/resolve-dpml-args.xsl @ 3521

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:sloot="http://www.isocat.org/ns/sloot">
    <xsl:param name="debug" select="false()"/>
    <xsl:template match="@*|node()">
        <xsl:copy>
            <xsl:apply-templates select="@*|node()"/>
        </xsl:copy>
    </xsl:template>
    <!-- skip over sloot-operator, which is this DPML script -->
    <xsl:template match="sloot-operator" priority="1"/>
    <xsl:template match="arguments/*">
        <xsl:copy>
            <xsl:apply-templates select="@*"/>
            <xsl:variable name="val" select="unparsed-text(.)"/>
            <xsl:if test="$debug">
                <xsl:message>DBG: <xsl:value-of select="name()"/>[<xsl:value-of select="."/>][<xsl:value-of select="$val"/>]</xsl:message>
            </xsl:if>
            <xsl:choose>
                <!-- snif if the value is XML -->
                <xsl:when test="matches(normalize-space($val),'&lt;.*&gt;')">
                    <xsl:copy-of select="doc(.)"/>
                </xsl:when>
                <xsl:otherwise>
                    <xsl:copy-of select="$val"/>
                </xsl:otherwise>
            </xsl:choose>
        </xsl:copy>
    </xsl:template>
</xsl:stylesheet>